Installing the new HP SUM (6.2.0) with MDT 2013

In the February 2014 release of Smart Update Manager (SUM), part of HP Service Pack for ProLiant, HP decided to change the setup behavior, and of course breaking my existing sequences for server deployments. The new SUM is available here: http://h17007.www1.hp.com/us/en/enterprise/servers/products/service_pack/spp/index.aspx and as part of their new strategy for server downloads (which sucks beyond belief), you need to register before you can download the ISO.

 

Changes

Prior to version 6.2.0 you run the hpsum.exe with a few command line switches. That file is now gone and replaced by hpsum.bat (!). Excuse me HP, this is 2014, not 1994.

Anyway, the hpsum.bat is just a wrapper for the new setup named hpsum_bin_x64.exe, which you find in the x64 folder of SUM.

The /express_install switch is gone and replaced by /s (or /silent), and to prevent the target server from writing back to the MDT deployment share, I recommend copying the repository to the local drive, and then use the /use_location switch. As with previous SUM version, HP don't follow any standards for exit codes either. In the HP world, exit code 1 means successful, but requires a reboot.

Shorthand, you need a wrapper, and below is one:

Ps. If you wonder why I'm using VBScript instead of my usual PowerShell scripting, it's because MDT 2013 still uses VBScript, and being able to tap into their functions is more important than re-writing everything in PowerShell.

The wrapper

Update 2014-03-12: The script has been updated to address an in issue when C:\Setup did not exist on the target machine (the script now creates it).

You can also download the script.

This wrapper copies the HP SUM to the local machine, runs the setup, and takes care of the non-standard exit codes.

<job id="Install-HPSUM">
<script language="VBScript" src="..\..\scripts\ZTIUtility.vbs"/>
<script language="VBScript"> 
 
'//----------------------------------------------------------------------------
'// Version: 1.2 - January 27, 2014 - Johan Arwidmark
'//
'// This script is provided "AS IS" with no warranties, confers no rights and 
'// is not supported by the authors or Deployment Artist. 
'//
'//----------------------------------------------------------------------------
 
'//----------------------------------------------------------------------------
'// Global constant and variable declarations
'//---------------------------------------------------------------------------- 
 
Option Explicit 
Dim iRetVal 
 
'//----------------------------------------------------------------------------
'// End declarations
'//---------------------------------------------------------------------------- 
 
'//----------------------------------------------------------------------------
'// Main routine
'//---------------------------------------------------------------------------- 
 
On Error Resume Next
iRetVal = ZTIProcess
ProcessResults iRetVal
On Error Goto 0 
 
'//---------------------------------------------------------------------------
'//
'// Function: ZTIProcess()
'//
'// Input: None
'// 
'// Return: Success - 0
'// Failure - non-zero
'//
'// Purpose: Perform main ZTI processing
'// 
'//---------------------------------------------------------------------------
 
Function ZTIProcess() 
 
    Dim sSetupFile
    Dim sArguments
    Dim sSourceFolder
    Dim sTargetFolder
     
    sSetupFile = "C:\Setup\HPSUM\x64\hpsum_bin_x64.exe"
    sArguments = "/s /use_location C:\Setup\HPSUM"
     
    oLogging.CreateEntry oUtility.ScriptName & ": Starting installation", LogTypeInfo
 
    If not oFSO.FolderExists("C:\Setup") then
        oLogging.CreateEntry oUtility.ScriptName & ": C:\Setup does not exist, creating it", LogTypeInfo
        oFSO.CreateFolder "C:\Setup"
    End if
 
    sSourceFolder = oUtility.ScriptDir & "\Source"
    sTargetFolder = "C:\Setup\HPSUM"
 
    If oFSO.FolderExists(sTargetFolder) then
        oLogging.CreateEntry oUtility.ScriptName & ": " & sTargetFolder & " already exists, aborting...", LogTypeError
        ZTIProcess = Failure
        Exit Function
    End if
 
    oFSO.CreateFolder sTargetFolder 
        oUtility.VerifyPathExists sTargetFolder
 
    oLogging.CreateEntry "Copying " & sSourceFolder & " folder to the local machine", LogTypeInfo
 
    ' Optional progess logging to the task sequence progress bar
    oLogging.ReportProgress "Copying " & sSourceFolder & " folder to the local machine", 20
 
    oFSO.CopyFolder sSourceFolder, sTargetFolder, true
         
    If not oFSO.FileExists(sSetupFile) then
        oLogging.CreateEntry oUtility.ScriptName & ": " & sSetupFile & " was not found, unable to install", LogTypeError
        ZTIProcess = Failure
        Exit Function
    End if
 
    oLogging.CreateEntry oUtility.ScriptName & ": Arguments is set to " & sArguments, LogTypeInfo        
 
    ' Optional progess logging to the task sequence progress bar
    oLogging.ReportProgress "Installing HP SUM", 60
 
    iRetVal = oUtility.RunWithHeartbeat("""" & sSetupFile & """ " & sArguments)
     
    if (iRetVal = 0) then 
        ZTIProcess = Success
    ElseIf (iRetVal = 1) then 
        ZTIProcess = Success
    ElseIf (iRetVal = 2) then 
        ZTIProcess = Success 
    ElseIf (iRetVal = 3) then 
        ZTIProcess = Success 
    ElseIf (iRetVal = 4) then 
        ZTIProcess = Success 
    Elseif (iRetVal = 5) then 
        ZTIProcess = Success 
    Elseif (iRetVal = 3010) then 
        ZTIProcess = Success 
    Else
        ZTIProcess = Failure
    End If
    oLogging.CreateEntry oUtility.ScriptName & ": Return code from command = " & iRetVal, LogTypeInfo
    oLogging.CreateEntry oUtility.ScriptName & ": Finished installation", LogTypeInfo
 
End Function
</script>
</job>

The Application

Simply download the HP SUM 6.2.0, mount the ISO, and copy the content of the hpswpackages folder to a folder named Source in your application folder.

Tip: If you only deploy Windows Server, you can reduce the size of the swpackages folder by deleting the Linux packages. Fellow ConfigMgr guru Nickolaj Andersen, posted a nice PowerShell one-liner on his blog which I modified to work with the MDT deployment share I had.

Get-ChildItem -Path "D:\MDTProduction\Applications\HP SUM 6.2.0\Source" -Recurse -Include *.rpm, *.scexe | Remove-Item -Force

Then copy the wrapper to the root of your application, and configure the application to run the wrapper.

Happy Deployment, Johan